AGF 언팩 스크립트 및 투명화 팁 공개

IDString "\x23\x00\x00\x00"

log MEMORY_FILE1 0 0 //temporary frame file

get FNAME basename
get FSIZE asize
get EXTNAME extension

goto 0xC
get FRAME_COUNT long

goto 0x4C0
for i = 1 <= FRAME_COUNT
   get FRAME_OFFSET long
   putarray 0 i FRAME_OFFSET
next i

set UNZIPED_SIZE_ADDR FRAME_COUNT
math UNZIPED_SIZE_ADDR * 8
math UNZIPED_SIZE_ADDR + 0x970
goto UNZIPED_SIZE_ADDR
get UNZIPED_SIZE long

for i = 1 <= FRAME_COUNT
   set FRAME_INFO_OFFSET i
   math FRAME_INFO_OFFSET * 8
   math FRAME_INFO_OFFSET + 0x96C
   goto FRAME_INFO_OFFSET
   get FRAME_WIDTH short
   get FRAME_HEIGHT short
   putarray 2 i FRAME_WIDTH
   putarray 3 i FRAME_HEIGHT
next i

set ZIP_SIZE_ADDR FRAME_COUNT
math ZIP_SIZE_ADDR * 8
math ZIP_SIZE_ADDR + 0x99C
goto ZIP_SIZE_ADDR
get ZIP_SIZE long

set ZIP_OFFSET ZIP_SIZE_ADDR
math ZIP_OFFSET + 4

comtype zlib
clog TEMPORARY_FILE ZIP_OFFSET ZIP_SIZE UNZIPED_SIZE

Open "." TEMPORARY_FILE

for i = 1 <= FRAME_COUNT
   print "---------------------Frame No. %i% of %FRAME_COUNT%---------------------"
   
   put 0x00 byte MEMORY_FILE1 //identsize;
   put 0x00 byte MEMORY_FILE1 //colurmaptype;
   put 0x02 byte MEMORY_FILE1 // imagetype;
   put 0x0000 short MEMORY_FILE1 // colourmapstart;
   put 0x0000 short MEMORY_FILE1 // colourmaplength;
   put 0x00 byte MEMORY_FILE1 
   put 0x0000 short MEMORY_FILE1 
   put 0x0000 short MEMORY_FILE1 
   getarray FRAME_WIDTH 2 i
   print "FRAMEWIDTH : %FRAME_WIDTH%"
   put FRAME_WIDTH short MEMORY_FILE1 
   getarray FRAME_HEIGHT 3 i
   print "FRAMEHEIGHT : %FRAME_HEIGHT%"
   put FRAME_HEIGHT short MEMORY_FILE1 
   put 0x20 byte MEMORY_FILE1 // bits per pixel
   put 0x28 byte MEMORY_FILE1 // image descriptor (101000)

   getarray CURRENTFRAMEOFFSET 0 i

   If i != FRAME_COUNT
       getarray CURRENTFRAMESIZE 0 (i+1)
       getarray CURRENTFRAMESIZE_BEFORE 0 i
       math CURRENTFRAMESIZE - CURRENTFRAMESIZE_BEFORE
       math CURRENTFRAMESIZE / 4
   Else
       get CURRENTFRAMESIZE asize
       getarray CURRENTFRAMESIZE_BEFORE 0 i
       math CURRENTFRAMESIZE - CURRENTFRAMESIZE_BEFORE
       math CURRENTFRAMESIZE / 4
   Endif

   set GOFURTHER CURRENTFRAMEOFFSET
   goto GOFURTHER

   for j = 0 < CURRENTFRAMESIZE
       set GOFURTHER CURRENTFRAMEOFFSET
       xmath GOFURTHER "GOFURTHER + (j * 4)"
       goto GOFURTHER

       get ALPHA byte
       get RED byte
       get GREEN byte
       get BLUE byte
       if ALPHA == 0x00 && GREEN == 0x00 && BLUE == 0x00
           for k = 0 < RED
               put 0xff byte MEMORY_FILE1
               put 0xff byte MEMORY_FILE1
               put 0xff byte MEMORY_FILE1
               put ALPHA byte MEMORY_FILE1
           next k
       else
           put BLUE byte MEMORY_FILE1
           put GREEN byte MEMORY_FILE1
           put RED byte MEMORY_FILE1
           put ALPHA byte MEMORY_FILE1  
       endif 
   next j

   string TGA_FILE_NAME = FNAME
   string TGA_FILE_NAME += "_"
   string TGA_FILE_NAME += i
   string TGA_FILE_NAME += ".tga"
   get TGA_SIZE asize MEMORY_FILE1
   log TGA_FILE_NAME 0 TGA_SIZE MEMORY_FILE1
   log MEMORY_FILE1 0 0
next i

참고해서 패킹 스크립트 짜고 싶은 사람은 짜서 쓰면 된다.

투명화에는 다른거 필요없이 이미지 크기는 변경안하고 TEMPORARY_FILE로 압축해제 된거에서 알파값만 전부다 00으로 바꾸고 다시 저장하면 100% 투명도로 되서 분해된 tga 파일들을 다시 결합하는 스크립트는 안짰다.

추가적으로 math FRAME_INFO_OFFSET + 0x968 로 하고 short 2개 get하면 각각 해당 프레임의 시작X점 시작Y점 이다.

( 예전에는 각 프레임에 투명한 부분을 그대로 저장했는데, 이미지 용량 줄이려고 최소한의 이미지만 담아서 프레임마다 크기가 다르다. )

원래 목적이  연옥술 투명화였던 만큼 따로 TGA 파일들을 결합하는 스크립트는 짜지 않을 예정이고, AK에서 스킬 투명화 옵션을 내놓아 준다면 순정으로 사용할 예정이다.

투명화 팁 : 언팩된 메모리에서 불투명도 부분만 수정하면 된다.

A의 값이 아래와 같은 불투명도를 나타냄.

FF = 100%
F2 = 95%
E6 = 90%
D9 = 85%
CC = 80%
BF = 75%
B3 = 70%
A6 = 65%
99 = 60%
8C = 55%
80 = 50%
73 = 45%
66 = 40%
59 = 35%
4D = 30%
40 = 25%
33 = 20%
26 = 15%
1A = 10%
0D = 5%
01 = 0.003% [ 00을 쓰면 00 XX 00 00 과 겹칠 가능성 때문에 이 값으로 지정. 충분히 안보임. ]

TEMPORARY_FILE 파일을 4바이트씩 끊어서 00 XX 00 00 인 부분은 그대로 두고 나머지 부분은 A R G B 순에서 A 값은 불투명도를 나타내므로 A를 원하는 투명도로 지정하고 저장한다. 이 부분은 스크립트로 만들면 간단하다.

이후에 아래의 메모리 압축 스크립트를 사용, 만들어진 파일은 1부에서 압축 용량을 나타내는 곳의 용량만 바꾸고 프레임 데이터를 나타내던 부분을  압축된 파일로 내용을 바꾸어 주면 끝이다.

get FNAME basename
get FSIZE asize

string UNZIPFILENAME = FNAME
string UNZIPFILENAME += ".zip"
comtype zlib_compress
clog UNZIPFILENAME 0 FSIZE FSIZE